pkgname=mate-image-viewer
pkgver=2011.08.31
pkgrel=1
pkgdesc="An image viewing and cataloging program for MATE"
arch=('i686' 'x86_64')
license=('GPL')
depends=('mate-desktop' 'libexif' 'lcms' 'desktop-file-utils' 'mate-icon-theme' 'exempi')
makedepends=('pkgconfig' 'mate-doc-utils' 'intltool')
options=('!emptydirs' '!libtool')
conflicts=('eom')
url="http://matsusoft.com.ar/projects"
groups=('mate-extras')
install=mate-image-viewer.install
source=(http://sourceforge.net/projects/matede/files/${pkgver}/${pkgname}.tar.gz/download)
sha256sums=('5cb6b424af115645061850d2c730744475ef979da36871e144291ddd4cae99bc')

build() {
	cd "${srcdir}/${pkgname}"

	PYTHON=/usr/bin/python2 ./autogen.sh --prefix=/usr --sysconfdir=/etc \
		--localstatedir=/var --disable-scrollkeeper || return 1

	make || return 1
}

package() {
    cd "${srcdir}/${pkgname}"

	make MATECONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install || return 1

	install -m755 -d "${pkgdir}/usr/share/mateconf/schemas"
	mateconf-merge-schema "${pkgdir}/usr/share/mateconf/schemas/${pkgname}.schemas" --domain ${pkgname} ${pkgdir}/etc/mateconf/schemas/*.schemas || return 1
	rm -f ${pkgdir}/etc/mateconf/schemas/*.schemas
}