From 0b0e6bc987da4fd88a7854ebb12bde705e92c428 Mon Sep 17 00:00:00 2001
From: Perberos <perberos@gmail.com>
Date: Thu, 1 Dec 2011 21:51:44 -0300
Subject: moving from https://github.com/perberos/mate-desktop-environment

---
 distro/archlinux/PKGBUILD                    | 43 ++++++++++++++++++++++++++++
 distro/archlinux/mate-control-center.install | 26 +++++++++++++++++
 2 files changed, 69 insertions(+)
 create mode 100644 distro/archlinux/PKGBUILD
 create mode 100644 distro/archlinux/mate-control-center.install

(limited to 'distro/archlinux')

diff --git a/distro/archlinux/PKGBUILD b/distro/archlinux/PKGBUILD
new file mode 100644
index 00000000..58d31bf9
--- /dev/null
+++ b/distro/archlinux/PKGBUILD
@@ -0,0 +1,43 @@
+pkgname=mate-control-center
+pkgver=2011.11.16
+pkgrel=1
+pkgdesc="The Control Center for MATE"
+arch=('i686' 'x86_64')
+license=('GPL')
+depends=('mate-window-manager' 'libxss' 'desktop-file-utils'
+         'mate-settings-daemon' 'libmatekbd' 'libcanberra'
+         'sound-theme-freedesktop' 'libunique' 'mate-menus'
+         'librsvg') #  'evolution-data-server>=2.29.92'
+makedepends=('mate-doc-utils' 'pkgconfig' 'intltool')
+options=('!emptydirs' '!libtool')
+url="http://matsusoft.com.ar/projects/mate/"
+groups=('mate')
+install=mate-control-center.install
+source=(http://sourceforge.net/projects/matede/files/${pkgver}/${pkgname}.tar.gz/download)
+sha256sums=('9e820258040b18d23ef536a146d4796b8d31b75b5bbc6915017f8b90abaee361')
+
+build() {
+    cd "${srcdir}/${pkgname}"
+    ./autogen.sh \
+        --prefix=/usr \
+        --sysconfdir=/etc \
+        --localstatedir=/var \
+        --disable-static \
+        --disable-scrollkeeper \
+        --disable-update-mimedb || return 1
+    #  --enable-aboutme <- this requires libebook (from evolution)
+    make || return 1
+}
+
+package() {
+    cd "${srcdir}/${pkgname}"
+
+    make MATECONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install || return 1
+
+    install -m755 -d "${pkgdir}/usr/share/mateconf/schemas"
+    mateconf-merge-schema "${pkgdir}/usr/share/mateconf/schemas/${pkgname}.schemas" --domain ${pkgname} ${pkgdir}/etc/mateconf/schemas/*.schemas || return 1
+    rm -f ${pkgdir}/etc/mateconf/schemas/*.schemas
+
+    # --disable-update-mimedb?
+    rm -f "${pkgdir}/usr/share/applications/mimeinfo.cache"
+}
diff --git a/distro/archlinux/mate-control-center.install b/distro/archlinux/mate-control-center.install
new file mode 100644
index 00000000..4cd00c7d
--- /dev/null
+++ b/distro/archlinux/mate-control-center.install
@@ -0,0 +1,26 @@
+pkgname=mate-control-center
+
+post_install() {
+	usr/sbin/mateconfpkg --install ${pkgname}
+	update-desktop-database -q
+	gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+	update-mime-database usr/share/mime
+}
+
+pre_upgrade() {
+	pre_remove $1
+}
+
+post_upgrade() {
+	post_install $1
+}
+
+pre_remove() {
+	usr/sbin/mateconfpkg --uninstall ${pkgname}
+}
+
+post_remove() {
+	update-desktop-database -q
+	gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+	update-mime-database usr/share/mime
+}
-- 
cgit v1.2.1