pkgname=mate-system-monitor
pkgver=2011.12.01
pkgrel=1
pkgdesc="A system monitor for MATE"
arch=(i686 x86_64)
license=('GPL')
depends=('libwnck' 'libgtop' 'gtkmm' 'librsvg' 'mate-icon-theme')
makedepends=('mate-doc-utils' 'pkgconfig' 'intltool')
groups=('mate-extras')
options=(!emptydirs !libtool)
url="http://matsusoft.com.ar/projects"
install=mate-system-monitor.install
source=(http://sourceforge.net/projects/matede/files/${pkgver}/${pkgname}.tar.gz/download)
sha256sums=('aa4d4d3a0939bf2a486a7ca39414b396d181e14a6afa9b9b398812d3735b2dce')

build() {
	cd "${srcdir}/${pkgname}"

	./configure --prefix=/usr --sysconfdir=/etc \
		--libexecdir=/usr/lib/${pkgname} \
		--localstatedir=/var --disable-static \
		--disable-scrollkeeper \
		--disable-schemas-install || return 1

	# there is some pre-compiled files on the tar
	make clean
	make || return 1
}

package() {
	cd "${srcdir}/${pkgname}"

	make MATECONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install || return 1
	#rm -f ${pkgdir}/usr/lib/*.la # can be used options=(!libtools)

	install -m755 -d "${pkgdir}/usr/share/mateconf/schemas"
	mateconf-merge-schema "${pkgdir}/usr/share/mateconf/schemas/${pkgname}.schemas" --domain ${pkgname} ${pkgdir}/etc/mateconf/schemas/*.schemas || return 1
	rm -f ${pkgdir}/etc/mateconf/schemas/*.schemas
}