add meson supportmeson

4 files changed, 59 insertions, 0 deletions

diff --git a/mate-user-guide/meson.build b/mate-user-guide/meson.build
new file mode 100644
index 0000000..4316dbd
--- /dev/null
+++ b/mate-user-guide/meson.build
@@ -0,0 +1,24 @@
+gnome.yelp(
+  'mate-user-guide',
+  sources: [
+    'index.docbook',
+    'legal.xml',
+    'gosbasic.xml',
+    'goscustdesk.xml',
+    'goseditmainmenu.xml',
+    'goscaja.xml',
+    'gosoverview.xml',
+    'gospanel.xml',
+    'gosstartsession.xml',
+    'gostools.xml',
+    'gosdconf.xml',
+    'gosdconfkeys.xml',
+    'gosfeedback.xml',
+    'glossary.xml',
+  ],
+)
+
+install_subdir(
+  'C/figures',
+  install_dir: join_paths(get_option('datadir'), 'help', 'C', 'mate-user-guide'),
+)
diff --git a/meson.build b/meson.build
new file mode 100644
index 0000000..3233fda
--- /dev/null
+++ b/meson.build
@@ -0,0 +1,29 @@
+project(
+  'mate-user-guide',
+  meson_version: '>= 0.61.2',
+  version: '1.28.0',
+)
+
+gnome = import('gnome')
+i18n = import('i18n')
+
+if get_option('nls')
+  subdir('po')
+endif
+
+desktop_in = configure_file(
+  input: 'mate-user-guide.desktop.in.in',
+  output: 'mate-user-guide.desktop.in',
+  copy: true,
+)
+
+i18n.merge_file(
+  input: desktop_in,
+  output: 'mate-user-guide.desktop',
+  type: 'desktop',
+  po_dir: join_paths(meson.project_source_root(), 'po'),
+  install: true,
+  install_dir: join_paths(get_option('datadir'), 'applications'),
+)
+
+subdir('mate-user-guide')
diff --git a/meson_options.txt b/meson_options.txt
new file mode 100644
index 0000000..37bec6c
--- /dev/null
+++ b/meson_options.txt
@@ -0,0 +1,5 @@
+option('nls',
+  type: 'boolean',
+  value: true,
+  description: 'Enable translations',
+)
diff --git a/po/meson.build b/po/meson.build
new file mode 100644
index 0000000..8d99fff
--- /dev/null
+++ b/po/meson.build
@@ -0,0 +1 @@
+i18n.gettext('mate-user-guide', preset: 'glib')